; Inno Setup script for 岩美酒库 Windows 客户端
; Compiled in CI:
;   ISCC /DAppVer=<ver> "/DSrcDir=<ReleaseDir>" "/DOutDir=<dist>" jiu-installer.iss
; Produces: <OutDir>\jiu-windows-x64-setup.exe

#ifndef AppVer
  #define AppVer "0.0.0"
#endif
#ifndef SrcDir
  #define SrcDir "."
#endif
#ifndef OutDir
  #define OutDir "."
#endif

#define MyAppName "岩美酒库"
#define MyAppExe "jiu_client.exe"
#define MyAppPublisher "岩美"

[Setup]
AppId={{A3F5C1E2-9B47-4D8A-B6E0-2C1D4F8A9E33}
AppName={#MyAppName}
AppVersion={#AppVer}
AppPublisher={#MyAppPublisher}
DefaultDirName={autopf}\Jiu
DefaultGroupName={#MyAppName}
DisableProgramGroupPage=yes
OutputDir={#OutDir}
OutputBaseFilename=jiu-windows-x64-setup
Compression=lzma2
SolidCompression=yes
WizardStyle=modern
ArchitecturesAllowed=x64
ArchitecturesInstallIn64BitMode=x64
UninstallDisplayName={#MyAppName}
UninstallDisplayIcon={app}\{#MyAppExe}
; 应用内更新时本应用会先退出再启动安装包；这些选项确保能顺利覆盖。
CloseApplications=yes
RestartApplications=no

[Languages]
; 简体中文语言文件随仓库提供（deploy/windows/ChineseSimplified.isl），
; compile-windows.sh 会把它和本 .iss 一起拷到构建目录，按相对路径引用，
; 不依赖 Inno Setup 安装目录是否自带（默认不带简中）。
Name: "chinesesimp"; MessagesFile: "ChineseSimplified.isl"

[Tasks]
Name: "desktopicon"; Description: "{cm:CreateDesktopIcon}"; GroupDescription: "{cm:AdditionalIcons}"; Flags: checkedonce

[Files]
Source: "{#SrcDir}\*"; DestDir: "{app}"; Flags: recursesubdirs createallsubdirs ignoreversion

[Icons]
Name: "{group}\{#MyAppName}"; Filename: "{app}\{#MyAppExe}"
Name: "{group}\卸载 {#MyAppName}"; Filename: "{uninstallexe}"
Name: "{commondesktop}\{#MyAppName}"; Filename: "{app}\{#MyAppExe}"; Tasks: desktopicon

[Run]
Filename: "{app}\{#MyAppExe}"; Description: "{cm:LaunchProgram,{#MyAppName}}"; Flags: nowait postinstall skipifsilent